home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amiga Plus 2004 #11
/
Amiga Plus CD - 2004 - No. 11.iso
/
AmiSoft
/
Util
/
dtype
/
WarpPCXdt.lha
/
WarpPCXdt
/
Install_WarpPCX
next >
Wrap
Text File
|
2004-08-04
|
17KB
|
534 lines
; $VER: Install_WarpPCX 1.5 (4.8.2004)
; by Oliver Roberts (oliver@futaura.co.uk)
(if (= (exists "Env:Language") 1)
(set @language (getenv "Language"))
)
(set #str-dtname "PCX")
;*****************
; English strings
;
(set #str-welcome (cat
"\n\nWarp%s.datatype\n\n"
"Copyright © 2003-2004 Oliver Roberts, All Rights Reserved.\n\n"
"This software is SHAREWARE, which means you are expected to register "
"if you find it useful after an evaluation period of 30 days, "
"and wish to continue using it.\n\n"
"www.warpdt.co.uk")
)
(set #str-kick3 "You must be running Kickstart 3.0 or higher to use datatypes.")
(set #str-installdt "Installing Datatype")
(set #str-installclass "Installing Warp%s.datatype class")
(set #str-installdes "Installing Descriptor")
(set #str-wrongcpu "You must have at least a 68020 processor to use this datatype.")
(set #str-oldpicdt (cat
"Warp%s.datatype needs picture.datatype v43 or higher.\n\n"
"Such a datatype is supplied with AmigaOS (3.5 or higher), P96 and CyberGraphX."
))
(set #str-backupdesc (cat
"You already have a %s datatype descriptor installed. Would you "
"like to keep a backup for safe-keeping?\n\n(if this is your first "
"time installing Warp%s.datatype, you probably should)"
))
(set #str-backup "Backup")
(set #str-overwrite "Overwrite")
(set #str-backupdir "Where should the %s descriptor be backed up to?")
(set #str-backingup "Backing up files")
(set #str-reboot (cat
"You may need to reboot for the changes to take effect.\n\n"
"Also, if you have any other PCX datatypes in DEVS:Datatypes, "
"you will probably have to remove them manually."
))
(set #str-askcpu "Choose which version of the library to install, to match your Amiga's processor type")
(set #str-patch "Creating the CPU specific version you asked for")
(set #str-askmorphos (cat
"It's possible to also have the 68k or WarpOS version installed (will "
"automatically be used if you boot without MorphOS):"
))
(set #str-earlyterm (cat
"Early Term is enabled in your WarpOS prefs - this usually causes "
"major problems, which affects this and other programs. It is "
"therefore recommended that you switch that setting off. Switch "
"Early Term off now?"
))
(set #str-off "Switch off")
(set #str-leave "Leave it as it is")
; v1.7
(set #str-woserr (cat
"The WarpOS version of Warp%s requires WarpUp 5.0 or higher. "
"WarpUp 4.0 is no longer supported, since it contains bugs which "
"prevent this datatype from working correctly, so you will need to "
"upgrade."
))
(set #str-classdir "Select where to install the datatype class\n(don't change from the default unless you know what you're doing)")
(set #str-descdir "Select where to install the datatype descriptor\n(don't change from the default unless you know what you're doing)")
;*****************
; Spanish strings (01.09.01) by Dámaso D. Estévez <amidde@arrakis.es>
;
(if (= @language "español") (
(set #str-welcome (cat
"\n\nWarp%s.datatype\n\n"
"Copyright © 2003-2004 Oliver Roberts.\nTodos los derechos reservados.\n\n"
"Este producto es \"SHAREWARE\": eso significa que ha de registrarse "
"transcurrido el período de evaluación de 30 días, si, encontrándolo útil, "
"desea seguir utilizándolo.\n\n"
"http://www.warpdt.co.uk")
)
(set #str-kick3 "Necesita disponer de la Kickstart 3.0 o superior para utilizar los tipos de datos.")
(set #str-installdt "Instalando el tipo de dato")
(set #str-installclass "Instalando la clase \"Warp%s.datatype\"")
(set #str-installdes "Instalando el descriptor")
(set #str-wrongcpu "Necesita disponer de al menos un microprocesador 68020 para utilizar este tipo de dato.")
(set #str-oldpicdt (cat
"\"Warp%s.datatype\" necesita del módulo \"picture.datatype\" versión 43 "
"o superior (es suministrado con la versión 3.5 del sistema operativo, "
"el paquete P96 y el paquete CyberGraphX)."
))
(set #str-backupdesc (cat
"Ya dispone del descriptor %s en su sistema.\n¿Desea que guarde "
"una copia de éste por motivos de seguridad?\n\n(si es la primera "
"vez que instala el tipo de dato Warp%s, debería responder afirmativamente)."
))
(set #str-backup "Copia de seguridad")
(set #str-overwrite "Sobreescribir")
(set #str-backupdir "¿Dónde debería guardar la copia de seguridad del descriptor \"%s\"?")
(set #str-backingup "Realizando la copia de seguridad de los ficheros")
(set #str-reboot (cat
"Puede que necesite reiniciar su equipo para que los cambios "
"tengan efecto.\n\nPor otro lado, si dispone de otro(s) tipo(s) de datos "
"PCX en \"DEVS:Datatypes\", probablemente deberá eliminarlo(s) de "
"su sistema de forma manual."
))
(set #str-askcpu "Elija qué versión debe ser instalada según el tipo de microprocesador de su equipo Amiga")
(set #str-patch "Se está creando la versión específica para el microprocesador elegido")
(set #str-earlyterm (cat
"La opción \"Terminador temprano\" (o \"Early Term\" en la versión en inglés) está activada en sus preferencias de WarpOS. "
"Esta opción genera problemas importantes que afecta a éste y otros "
"programas, de manera que se recomienda que la desactive. ¿Quiere "
"desconectar dicha opción ahora?"
))
(set #str-off "Desactivarla")
(set #str-leave "Dejarla tal cual")
; v1.7
(set #str-woserr (cat
"La versión WarpOS de \"Warp%s\" requiere la versión 5.0 o superior de WarpUp. "
"Ya no se ofrece soporte para la versión 4.0 de WarpUp debido a que contiene "
"errores que impiden que este tipo de dato funcione correctamente... o sea, "
"que necesita actualizarse."
))
(set #str-classdir "Elija dónde ha de instalarse la clase\n(no cambie la ruta/camino por defecto a menos que sepa lo que está haciendo).")
(set #str-descdir "Elija dónde instalar el descriptor\n(no cambie la ruta/camino por defecto a menos que sepa lo que está haciendo).")
))
;*****************
; French strings (19/07/01) by Bovier Philippe
;
(if (= @language "français") (
(set #str-kick3 "Au minimum un Kickstart 3.0 ou supérieur est requis pour utiliser cette datatype.")
(set #str-installdt "Installation de la Datatype")
(set #str-installclass "Installation de la classe Warp%s.datatype")
(set #str-installdes "Installation de la Description")
(set #str-wrongcpu "Au minimum un processeur 68020 est requis pour utiliser cette datatype.")
(set #str-oldpicdt (cat
"Warp%s.datatype nécesite la picture.datatype v43 ou supérieur.\n\n"
"Cette datatype est fournis avec l'AmigaOS 3.5, P96 et CyberGraphX."
))
(set #str-backupdesc (cat
"Vous possédez déjà une description %s installé. Désirez-vous "
"garder une sauvegarde de cette description ?\n\n(Si ceci est votre première "
"installation de la Warp%s.datatype, vous devriez, probablement)"
))
(set #str-backup "Sauvegarder existant")
(set #str-overwrite "Remplacer existant")
(set #str-backupdir "Ou désirez-vous que la description %s soit sauvegardée ?")
(set #str-backingup "Sauvegarde des fichiers")
(set #str-reboot "Il est nécessaire de redémarrer votre Amiga pour que les changements soient pris en compte.")
(set #str-askcpu "Choisissez la version de la librairie à installer, en concordance avec votre processeur 68XXX ")
(set #str-patch "Création de la version spécifique à votre processeur")
(set #str-askmorphos (cat
"Il est possible d'avoir aussi la version 68k ou WarpOS installé (qui "
"sera automatiquement utilisée si vous démarrez votre Amiga avec ou sans MorphOS):"
))
(set #str-earlyterm (cat
"Early Term est activé dans vos préférences WarpOS - Ce qui habituellement cause "
"d'importants problèmes, qui affectent ce et d'autres programmes. Il est "
"chaudement recommandé de désactiver ce paramètre. Désactivation du paramètre "
"Early Term maintenant ?"
))
(set #str-off "Désactivation du paramètre")
(set #str-leave "Le laisser tel qu'il est")
))
;*****************
; Polish strings (c) 13.10.2003 by Mariusz Danilewicz <mandi@interia.pl>
;
(if (= @language "polski") (
(set #str-welcome (cat
"\n\nWarp%s.datatype\n\n"
"Copyright (c) 2003-2004 Oliver Roberts, Wszelkie prawa zastrzeûone.\n\n"
"Oprogramowanie to ma status SHAREWARE, co oznacza, iû powinieneô je zarejestrowaê "
"jeôli po trzydziestodniowym okresie testowym okaûe sië, iû jest ono Ci pomocne "
"i bëdziesz chciaî kontynuowaê jego uûywanie.\n\n"
"www.warpdt.co.uk")
)
(set #str-kick3 "Musisz uûywaê Kickstartu w wersji 3.0 lub nowszej aby korzystaê z datatype'ów.")
(set #str-installdt "Instalacja Datatype'u")
(set #str-installclass "Instalujë klasë Warp%s.datatype")
(set #str-installdes "Instalacja pliku opisu")
(set #str-wrongcpu "Aby uûywaê tego datatype'u musisz mieê procesor co najmniej 68020.")
(set #str-oldpicdt (cat
"Warp%.datatype wymaga picture.datatype w wersji v43 lub nowszej.\n\n"
"Taki datatype jest dostarczany z AmigaOS 3.5, P96 i CyberGraphX."
))
(set #str-backupdesc (cat
"Masz juû zainstalowany plik opisu datatype'u %s. Czy chcesz utworzyê "
"kopië bezpieczeïstwa tego pliku?\n\n(Jeôli pierwszy raz instalujesz "
"Warp%s.datatype, powinieneô utworzyê kopië bezpieczeïstwa)"
))
(set #str-backup "Utwórz kopië bezpieczeïstwa")
(set #str-overwrite "Zastâp")
(set #str-backupdir "Gdzie zapisaê kopië bezpieczeïstwa pliku opisu datatype'u %s?")
(set #str-backingup "Tworzenie kopii bezpieczeïstwa")
(set #str-reboot (cat
"Aby uûywaê nowego datatype'u powinieneô uruchomiê ponownie komputer.\n\n"
"Dodatkowo jeôli w katalogu DEVS:Datatypes masz zainstalowane inne datatype'y dla formatu PCX, "
"prawdopodobnie bëdziesz musiaî je usunâê rëcznie."
))
(set #str-askcpu "Wybierz którâ wersjë biblioteki chcesz zainstalowaê, odpowiadajâcâ procesorowi w Twoim komputerze")
(set #str-patch "Tworzenie wersji specjalnie dla okreôlonego przez Ciebie procesora")
(set #str-askmorphos (cat
"Jest moûliwe zainstalowanie zarówno wersji dla procesora 68k oraz dla sytemu WarpOS (bëdzie "
"ona uûywana automatycznie w przypadku nieuruchamiania systemu MorphOS):"
))
(set #str-earlyterm (cat
"Opcja 'Early Term' jest wîâczona w Twoich preferencjach systemu WarpOS - przewaûnie opcja ta "
"powoduje powaûne bîëdy, wpîywajâce na ten i inne programy. Dlatego teû "
"zaleca sië wyîâczenie tej opcji. Wyîâczyê të opcjë teraz?"
))
(set #str-off "Wyîâcz")
(set #str-leave "Pozostaw bez zmian")
; v1.7
(set #str-woserr (cat
"Wersja Warp%s dla systemu WarpOS wymaga WarpUp w wersji 5.0 lub nowszej. "
"WarpUp w wersji 4.0 nie jest juû dîuûej obsîugiwany, gdyû zawiera bîëdy uniemoûliwiajâce "
"poprawne dziaîanie tego datatype'u, dlatego teû powinieneô dokonaê uaktualnienia."
))
(set #str-classdir "Wybierz gdzie chcesz zainstalowaê plik klasy datatype'u\n(nie zmieniaj domyôlnego katalogu, chyba, ûe jesteô pewien co czynisz)")
(set #str-descdir "Wybierz gdzie chcesz zainstalowaê plik opisu datatype'u\n(nie zmieniaj domyôlnego katalogu, chyba, ûe jesteô pewien co czynisz)")
))
;**********************
; Compatibility checks
;
(set #installer-ver (/ @installer-version 65536))
(set #propchoices (if (< #installer-ver 42) "" "\x1b[2p"))
(set @default-dest "")
(set #cpustr (database "cpu"))
(set #osver (/ (getversion) 65536))
(if (< #osver 39)
(abort #str-kick3)
)
(set #cpu -1)
(if (= #cpustr "68020") (set #cpu 0))
(if (= #cpustr "68030") (set #cpu 1))
(if (= #cpustr "68040") (set #cpu 2))
(if (= #cpustr "68060") (set #cpu 3))
(if (< #cpu 0) (abort #str-wrongcpu))
(set #warpos 0)
(set #morphos 0)
(set #os4 0)
(if (AND (>= #cpu 2) (exists "LIBS:powerpc.library"))
(
(set #ppcver (/ (getversion "LIBS:powerpc.library") 65536))
(set #warpver (/ (getversion "LIBS:warp.library") 65536))
(if (AND (>= #ppcver 16) (>= #warpver 5))
(
(set #warpos 1)
(set #cpu 5)
)
)
)
)
(if (>= #cpu 2)
(
(if (= (run "C:Version >NIL: MorphOS" (safe)) 0)
(set #morphos 1)
)
)
)
(if (AND (>= #osver 50) (NOT #morphos))
(
(set #os4 1)
(set #cpu 4)
)
)
(set #picdt-ok 0)
(if #morphos
(
(if (exists "SYS:Classes/Datatypes/picture.datatype.elf")
(
(set #pdtver (/ (getversion "SYS:Classes/Datatypes/picture.datatype.elf") 65536))
(if (>= #pdtver 43) (set #picdt-ok 1))
)
)
(if (AND (NOT #picdt-ok) (exists "MOSSYS:Classes/Datatypes/picture.datatype.elf"))
(
(set #pdtver (/ (getversion "MOSSYS:Classes/Datatypes/picture.datatype.elf") 65536))
(if (>= #pdtver 43) (set #picdt-ok 1))
)
)
(if (AND (NOT #picdt-ok) (exists "MOSSYS:Classes/Datatypes/picture.datatype"))
(
(set #pdtver (/ (getversion "MOSSYS:Classes/Datatypes/picture.datatype") 65536))
(if (>= #pdtver 43) (set #picdt-ok 1))
)
)
)
)
(if (NOT #picdt-ok)
(if (exists "SYS:Classes/Datatypes/picture.datatype")
(
(set #pdtver (/ (getversion "SYS:Classes/Datatypes/picture.datatype") 65536))
(if (OR (>= #pdtver 43) (= #os4 1)) (set #picdt-ok 1))
)
)
)
(if (= #picdt-ok 0)
(abort (#str-oldpicdt #str-dtname))
)
;*************
; Here we go!
;
(welcome)
(message (#str-welcome #str-dtname))
(set #defcpu #cpu)
(if #morphos (set #cpu 6))
(set #cpu
(askchoice
(prompt #str-askcpu)
(choices (cat #propchoices "68020") "68030" "68040" "68060" "PowerPC (OS4)" "PowerPC (WarpOS)" "PowerPC (MorphOS)")
(default #cpu)
(help @askchoice-help)
)
)
(set #morphos (= #cpu 6))
(if #morphos
(set #cpu
(askchoice
(prompt #str-askmorphos)
(choices (cat #propchoices "68020") "68030" "68040" "68060" "PowerPC (OS4)" "PowerPC (WarpOS)" "Only install MorphOS version")
(default #defcpu)
(help @askchoice-help)
)
)
)
(if (AND (= #cpu 5) (= #warpos 0))
(
(message (#str-woserr #str-dtname))
(set #cpu
(askchoice
(prompt #str-askcpu)
(choices (cat #propchoices "68020") "68030" "68040" "68060" "PowerPC (OS4)" "PowerPC (MorphOS)")
(default #defcpu)
(help @askchoice-help)
)
)
(set #morphos (= #cpu 5))
(if #morphos
(set #cpu
(askchoice
(prompt #str-askmorphos)
(choices (cat #propchoices "68020") "68030" "68040" "68060" "PowerPC (OS4)" "Only install MorphOS version")
(default #defcpu)
(help @askchoice-help)
)
)
)
(if (= #cpu 5) (set #cpu 6))
)
)
(if (= #cpu 5)
(if (= (getenv "powerpc/earlyterm") "1")
(if (askbool
(prompt #str-earlyterm)
(help "")
(default 0)
(choices #str-off #str-leave)
)
(
(textfile
(dest "ENV:powerpc/earlyterm")
(append "0")
)
(textfile
(dest "ENVARC:powerpc/earlyterm")
(append "0")
)
)
)
)
)
(set #descdir
(askdir
(prompt #str-descdir)
(help @askdir-help)
(default "DEVS:Datatypes")
)
)
(set #classdir
(askdir
(prompt #str-classdir)
(help @askdir-help)
(default "SYS:Classes/Datatypes")
)
)
(working #str-installdt)
(if (= #cpu 0)
(set #dtname "Classes/Datatypes/WarpPCX.datatype.020")
)
(if (= #cpu 1)
(
(working #str-patch)
(run "spatch -ot:WarpPCX.datatype.030 -pclasses/datatypes/WarpPCX.datatype.030.pch classes/datatypes/WarpPCX.datatype.020" (safe))
(set #dtname "t:WarpPCX.datatype.030")
)
)
(if (= #cpu 2)
(
(working #str-patch)
(run "spatch -ot:WarpPCX.datatype.040 -pclasses/datatypes/WarpPCX.datatype.040.pch classes/datatypes/WarpPCX.datatype.020" (safe))
(set #dtname "t:WarpPCX.datatype.040")
)
)
(if (= #cpu 3)
(
(working #str-patch)
(run "spatch -ot:WarpPCX.datatype.060 -pclasses/datatypes/WarpPCX.datatype.060.pch classes/datatypes/WarpPCX.datatype.020" (safe))
(set #dtname "t:WarpPCX.datatype.060")
)
)
(if (= #cpu 4)
(set #dtname "Classes/Datatypes/WarpPCX.datatype.os4")
)
(if (= #cpu 5)
(set #dtname "Classes/Datatypes/WarpPCX.datatype.wos")
)
(if (< #cpu 6)
(
(copyfiles
(help @copyfiles-help)
(prompt (#str-installclass #str-dtname))
(source #dtname)
(dest #classdir)
(newname "WarpPCX.datatype")
(confirm)
)
(if (AND (> #cpu 0) (< #cpu 4))
(delete #dtname (safe))
)
)
)
(if #morphos
(copyfiles
(help @copyfiles-help)
(prompt (#str-installclass #str-dtname))
(source "Classes/Datatypes/WarpPNG.datatype.mos")
(newname "WarpPNG.datatype.elf")
(dest #classdir)
(confirm)
)
)
(if (exists (tackon #descdir "PCX"))
(if (askbool
(prompt (#str-backupdesc #str-dtname #str-dtname))
(help "")
(default 0)
(choices #str-backup #str-overwrite)
)
(
(set #bakdir
(askdir
(prompt (#str-backupdir #str-dtname))
(help @askdir-help)
(default "SYS:Storage/Datatypes")
)
)
(copyfiles
(help @copyfiles-help)
(prompt #str-backingup)
(source (tackon #descdir ("PCX")))
(dest #bakdir)
(infos)
(confirm)
)
)
)
)
(if (= #cpu 4)
(set #descname "Devs/Datatypes/PCX.os4")
(set #descname "Devs/Datatypes/PCX.68k")
)
(copyfiles
(help @copyfiles-help)
(prompt #str-installdes)
(source #descname)
(newname "PCX")
(dest #descdir)
(confirm)
)
(copyfiles
(help @copyfiles-help)
(prompt #str-installdes)
(source "Devs/Datatypes/PCX.info")
(dest #descdir)
(confirm)
)
(run ("C:AddDataTypes \"%s\" >NIL: REFRESH" (tackon #descdir "#?")))
(run "C:Avail FLUSH >NIL:")
(exit #str-reboot)